Assembly optimering

struct rgb {
	unsigned char	red;
	unsigned char	green;
	unsigned char	blue;
};

void InvertImage_optimized4(rgb *picture, unsigned int width, unsigned int height) {

__asm {
	push	ebx

	mov	ebx, [picture]

	// check the alignment (aligned by 8)
	mov	eax, ebx
	test	eax, 7
	jnz	ready

	mov	eax, dword ptr [width]	// width
	imul	eax, dword ptr [height]	// width * height
	imul	eax, 3			// width * height * sizeof(unsigned char) * 3
	add	eax, ebx			// add base address
	mov	ecx, eax


	jmp	first_time

	// read two dword per loop
main_loop:
	mov	dword ptr [ebx-4], eax	// U
first_time:
	mov	edx, dword ptr [ebx]		// V (pairs)

	add	ebx, 4			// U
	xor	edx, 0FFFFFFFFh		// V (pairs)

	mov	eax, dword ptr [ebx]	// U
	add	ebx, 4			// V (pairs)

	xor	eax, 0FFFFFFFFh		// U
	mov	dword ptr [ebx-8], edx	// V (pairs)

	cmp	ebx, ecx			// U
	jb	main_loop			// V (pairs)

	mov	dword ptr [ebx-4], eax
ready:

	pop	ebx
}

}

void InvertImage_optimized5(rgb *picture, unsigned int width, unsigned int height) {

unsigned int dummy[2];

dummy[0] = 0xFFFFFFFF;
dummy[1] = 0xFFFFFFFF;

__asm {

	push	ebx

	mov	ebx, [picture]

	// check the alignment (aligned by 8)
	mov	eax, ebx
	test	eax, 7
	jnz	ready

	mov	eax, dword ptr [width]
	imul	eax, dword ptr [height]
	imul	eax, 3
	add	eax, ebx
	mov	ecx, eax

	movq	mm1, [dummy]

	// read a quad word per loop
main_loop:			
	movq	mm0, [ebx]
	pxor	mm0, mm1
	movq	[ebx], mm0

	add	ebx, 8
	cmp	ebx, ecx
	jb	main_loop

ready:

	pop	ebx
}

}